Piloter un moteur pas-à-pas NEMA 17 à distance via Arduino et NRF24L01

				
					// Carte : Arduino UNO
// Atelier de la Robotique

#include <SPI.h>
#include <nRF24L01.h>
#include <RF24.h>
    
RF24 radio(9, 10); // CE, CSN
const byte adresse[6] = "motor";

struct Data {
  int x;
  int y;
  bool bouton;
};

Data data;

#define DIR_PIN 2
#define STEP_PIN 3

const int X_CENTER = 330; // X_CENTER : Joystick au Repos
const int X_MIN = 0; // X_MIN: Joystick vers le Bas
const int X_MAX = 670; // X_MAX: Joystick vers le Haut
const int DEADZONE = 40;

volatile int currentDelay = 0; // durée entre pas
volatile bool moteurActif = false;
volatile bool sens = HIGH;

unsigned long lastStepTime = 0;

void setup() {
  Serial.begin(9600);

  pinMode(DIR_PIN, OUTPUT);
  pinMode(STEP_PIN, OUTPUT);

  radio.begin();
  radio.openReadingPipe(0, adresse);
  radio.setPALevel(RF24_PA_LOW);
  radio.startListening();

  Serial.println("Récepteur prêt !");
}

void loop() {
  // ----  Réception radio ----
  if (radio.available()) {
    radio.read(&data, sizeof(Data));

    int deviation = data.x - X_CENTER;

    if (abs(deviation) < DEADZONE) {
      moteurActif = false;
      currentDelay = 0;
    } else {
      moteurActif = true;
      sens = (deviation > 0);
      digitalWrite(DIR_PIN, sens ? HIGH : LOW);
      currentDelay = map(abs(deviation), 0, max(X_CENTER - X_MIN, X_MAX - X_CENTER), 1200, 200);
      currentDelay = constrain(currentDelay, 200, 1200);
    }
  }

  // ---- Génération d’impulsions fluide ----
  if (moteurActif && currentDelay > 0) {
    unsigned long now = micros();
    if (now - lastStepTime >= (unsigned long)currentDelay) {
      lastStepTime = now;
      digitalWrite(STEP_PIN, HIGH);
      delayMicroseconds(5);   // impulsion courte (5–10 µs)
      digitalWrite(STEP_PIN, LOW);
    }
  }
}